|
この実験ではＣＰＵの負担を軽くする為に小規模なＰＬＤを使って３相誘導モーターのドライブ専用ＩＣを試作しています。
制御方法は、なるべくLOWコストなＰＬＤで作ることを目標に波形の発生方法を検討した結果、電圧ベクトル制御法
という面白い方法がありましたのでこれをロジック化してみました。（参考 文献１．）
電圧ベクトルの発生
電圧ベクトル制御法は６個のパワースイッチング素子を図１のように６通りのＯＮ／ＯＦＦをくり返させます。
 図１ 図２
この６回がＳｉｎ波の１周期となります。 だだし、これだけでは図２のような電流がモーターに流れ一種のステッピングモーターに
似た状態となってなめ らかな回転が出来ません。（６ステップインバータと言います）
そこでパワースイッチング素子を制御して相間電
圧がＳＩＮ波となるようにします。
図３にそのＰＷＭを生成する為の状態図を示します。
 図３
ＨＥＸ０からＨＥＸ５(STEP0からSTEP5)まで6通りの状態に変化していきますが、ＶＣＣまたはＧＮＤマークは
その状態の時、１００％ のディユーティでＶＣＣ及びＧＮＤに接続される事を意味します。このＶＣＣとＧＮＤマークを
ゼロベクトルと呼びま す。 実際には波形データの生成は図４に示すように表計算ソフトによりＳｉｎ波形を調整
しながら作ります。
ＳＩＮ波の分解能は５ＢＩＴとした為、ゼロから３１になりますが、安全の為最大ＯＮ幅８０％としましたので
ゼロから２６となります。
波形の合成
図５に、この表より各相の出力電圧波形を示しますが、とてもＳＩＮ波形とは言えませが。
しかし、Ｕ−Ｖ，Ｖ−Ｗ， Ｗ−Ｕの各相関電圧波形は図６に示す様様にきれいなＳＩＮ波形となります。（不思議ですね）
 図５,図６
PLDの構成
ＰＬＤの内部構成 図７にＰＬＤの内部構成を示します。
 図７
３Ｂｉｔカウンタ（ＨＥＸ）は回転速度調整ＣＬＯＣＫによってカウントされ、６通 りのパワー素子の動作モード
（６ステップインバータ）を発生させます。
さらに３ＢＩＴカウンタＣＳＴＥＰにより、その １つの状態を時間的に５つに分解したＰＷＭ波形をつくりＳＩＮ波を発生させます。
したがって、ＳＩＮ波１周期は３０ステップの分解能となります。
ＰＷＭ波は５ＢＩＴカウンタｖｅｃとＳＩＮ波の固定データを参照比較する事により発生しています。
この固定データ ですが、図４の表計算で求めました。
Ｕ，Ｖ，Ｗのデータはそれぞれ１２０度ずれた位置に配置されています。
データは６つのデータのブロックになっていますが、その中で連続した２６と０のブロックであるゼロベクトルは、
図 ３のＶＣＣ及びＧＮＤに相当し、固定データとして扱いません。
残る４つのデータですが、表中の太字の２つのブ
ロックの値を反転させる事により残り２つのデータを発生出来ます。
結局、固定データは表中太字部分の１０ 個（２つのブロック）のみとなり回路規模を小さくする事が出来ました。
６相ＰＷＭの発生 Ｕ，Ｖ，Ｗ、３つのＰＷＭ信号は６個のパワー素子をドライブする為にそれぞれを反転したＵ，Ｖ，Ｗを
作り出しま す。
ただし、パワー素子にはTonおよびToffによる動作の遅れがある為、Ｕ，Ｖ，Ｗを反転しただけでは上側と下側のパワー素子が
同時ＯＮを避ける為、遅延回路を設けています。
この回路はＰＬＤの外部にＣＲによる積分回路を追加して回路を簡素化しています。
 試作基板
ＰＷＭ波発生回路 ＬＯＧＩＣ回路はザイリンクス社のＸＣ９５３６で
ゲート数が８００ゲートのものを使用しました。
試験回路
回路図ダウンロード 3pinv.bmp (3pinv.zip)
回転数制御，トルク制御
このＰＬＤにはモーターの回転速度を指示する為のＣＬＯＣＫと
出力電圧を可変してトルク制御する為のＣＬＯＣＫが必要です。
各、ＣＬＯＣＫは７４ＨＵ０４による簡単なアナログ発振器で作製しました。
モータードライバ
ＰＬＤから出力されたＰＷＭ波は２００Ｖクラスのモーターをドライブしますので今回はＩＲ社のＩＲ２１１０による
ドライバーを通して パワーＭＯＳＦＥＴをドライブしています。
ＩＲ２１１０はＣＭＯＳロジックレベルの信号で負荷容量の大きなパワーＭＯＳＦＥＴをドライブする為のＩＣで
入出 力の絶縁耐圧は５００Ｖです。
また、このＩＣは上側（ハイサイド）のパワーＭＯＳＦＥＴの制御信号用の電源を作る為のブートストラップ回路が 簡単に
構成出来、電源回路をシンプルなものにする事が出来ます。
モーター用電源回路は、商用電源（ＡＣ１００Ｖ）を全波整流してＤＣ１４０Ｖを作りました。
実験には安全の為にスライダックを通しています。
 International Rechifier DATA SHEET
ＰＬＤへの回路書き込み
ＸＣ９５００シリーズは配置配線データを内部のフラッシュROMに記憶させるので、その為のデータ書き込み回路を搭載しています。
といっても回路的には４本の信号線とコネクタのみで、ザイリンクス社のＪＴＡＧプログラマ ParallelCableIIIと呼ばれる
書き込み装置を通しパソコンからデータを回路情報をダウンロードします。
過電流保護制御
モーター過電流制御 モーターに過大な電流が流れた時、瞬時にFETを停止させ回路を保護する為に外部シャント抵抗器による
電流検出を行いフィルタを通してＰＬＤ内のラッチ回路が働きます。
この時、ＰＷＭ出力はスリーステート状態となり外部抵抗によりＬｏレベルに保たれ全てのパワー素子はＯＦＦとなります。
またドライバーＩＣのＳＤ（シャットダウン）端子もＨｉとなり保護動作を行います。
ソフトウエア
開発環境
使用したＰＬＤの開発ＴＯＯＬソフトウエアはザイリンクス社のＦｏｕｎｄａｔｉｏｎ Ver1.4で付属のＡＢＥＬ言語で作成しました。
ＤＥＢＵＧは付属のＡＬＤＥＣ社のシミュレータで行いこの後XC9536にインプリメントします。
これにより 生成されたデータはパソコンのプリンタ用コネクタからXilinx社の専用のＪＴＡＧプログラマ Parallel Cable ３を通し、
基板 上のＰＬＤに書き込みます。
XC9500シリーズは低速な処理部分（セル）は消費電力を下げるように指定出来るので、この実験では全て低消費電力モードで
行いました。
また未使用ピン全てをグランドピンに指定する事が出来、この様な大きなノイズを発生する回路での誤動作を防止しています。
さらに出力回路はスルーレートを高速あるいは低速に設定出来るため今回の実験では不必要な帯域のノイズの発生を少なくする
目的で低速モードとしました。
ソフトウエア、資料に関してはCQ出版社
トランジスタ技術誌のダウンロードページ"1999年5月号 ３相誘導モータのドライブ専用ＰＬＤの試作"を参照下さい。
ABELソースコード ダウンロード ABEL.TXT
module INV3P
Title '3phase induction motor
control'
////////////////////////////////////////////////////////////
// ３相電圧ベクトル制御 インバータ コントローラ
// PLD : Xilinx XC9536 PC-44
// MiniProbe
// Kazuhiro Omura
// 開発ツール ： Foundation
1.4 XABEL
// コンパイル及びインプリメント時の注意
// １．Foundation 1.4でのＡＢＥＬコンパイラは日本語対応と
// なっていない為、コンパイル時は日本語の注釈を外す事。
// ２．インプリメントツールのオプションで以下の設定を行う事。
// ａ．オプチマイザをセル面積優先に設定する事。
// ｂ．全セル低消費電力モードを設定する事。
// ｃ．未使用のピンを全てＧＮＤピンに設定する事。
////////////////////////////////////////////////////////////
Declarations
carrer PIN 5; //回転数クロック入力
vf PIN 6; //出力電圧クロック入力
U pin 38 istype 'com'; //Ｕ相ベクトル電圧出力
V pin 36 istype 'com'; //Ｖ相 ”
W pin 34 istype 'com'; //Ｗ相 ”
vectorx node istype 'com';
//ＰＷＭ幅 ベクトルｘ
vectory node istype 'com';
// ” ベクトルｙ
vectorz node istype 'com';
// ”ゼロベクトルｚ
ivectorx node istype 'com'; // ”反転ベクトルｘ
ivectory node istype 'com'; // ”反転ベクトルｙ
UP pin 18 istype 'com'; //Ｕ相上アーム出力
UN pin 20 istype 'com'; //Ｕ相下アーム出力
UDL pin 37; //Ｕ相ディレイ入力
VP pin 22 istype 'com'; //Ｖ相上アーム出力
VN pin 24 istype 'com'; //Ｖ相下アーム出力
VDL pin 35; //Ｖ相ディレイ入力
WP pin 26 istype 'com'; //Ｗ相上アーム出力
WN pin 28 istype 'com'; //Ｗ相下アーム出力
WDL pin 33; //Ｗ相ディレイ入力
PWM pin 44 ; //Hi:６相出力停止(Hi-Z)
Lo:運転
OCIN pin 42; //過電流信号入力 ↑で停止
OCOUT pin 40 istype 'com'; //過電流停止信号出力
OCLATCH node istype 'reg'; //過電流信号ラッチ
cstep2..cstep0 node istype 'reg';
//最少刻み状態 カウンタ
hex2..hex0 node istype 'reg';
//６ステップ状態 カウンタ
vec4..vec0 node istype 'reg';
//ベクトル発生用カウンタ
vecshot1..vecshot0 node istype
'reg'; //ベクトルカウンタ
リセット回路
vecshotout node istype 'com';
//ベクトルカウンタ
リセット出力
cstep = [cstep2..cstep0];
hex = [hex2..hex0];
vec = [vec4..vec0];
vecshot = [vecshot1..vecshot0];
//////////////////////////////////////////////////////////////////////////////
Equations
cstep.clk = carrer ; //モーターの回転スピードはcstep及び
hex.clk = carrer; //hexのクロック(carrer)で可変する
vec.clk = vf; //出力電圧調整はvecへクロック(vf)を
vecshot.clk = vf; //与え可変する
cstep := (cstep + 1) & (cstep
<= 3);
//１周期３０ステップの分解能なので
when (cstep == 4) then //最少刻みカウンタcstepが５ステップ
hex := (hex + 1) & (hex <=
4); //数えるごとに６ステップインバータhex
else hex := hex; //の状態がインクリメントされる。
//ベクトルの発生
when (vec < 30) then //出力電圧調整カウンタvecが
{vec := vec + 1;} //何らかの原因で３０を越えて
else when (vecshotout == 1) then
//しまった時、ＰＷＭ ＯＮ幅を
{vec := 0;} //これ以上にしない。
else {vec := vec;} //又、次のステップに移った時、
//vecカウンタをリセットさせる。
//カウンタvecをリセットさせる為のoneshot回路
vecshotout = (vecshot0 &
!vecshot1);
//carrerクロックの立ちあがり
vecshot1 := vecshot0; //でvecをリセットする為の微分
vecshot0 := carrer; //回路。
//最少刻みカウンタの状態によりvectorxとvectory及び、それらを反転した
//ivectorxとivectoryにベクトル（ＯＮ幅）をＳＥＴする。
when (cstep == 0) then
{vectorx = (vec <= 3); vectory
= (vec
<= 24);
ivectorx = (!vec >= 3); ivectory
= (!vec
>= 24);}
when (cstep == 1) then
{vectorx = (vec <= 8); vectory
= (vec
<= 25);
ivectorx = (!vec >= 8); ivectory
= (!vec
>= 25);}
when (cstep == 2) then
{vectorx = (vec <= 13); vectory
= (vec
<= 26);
ivectorx = (!vec >= 13); ivectory
= (!vec
>= 26);}
when (cstep == 3) then
{vectorx = (vec <= 17); vectory
= (vec
<= 25);
ivectorx = (!vec >= 17); ivectory
= (!vec
>= 25);}
when (cstep == 4) then
{vectorx = (vec <= 21); vectory
= (vec
<= 24);
ivectorx = (!vec >= 21); ivectory
= (!vec
>= 24);}
//ゼロベクトル vectorzにベクトル（ＯＮ幅２６(固定値)）をＳＥＴする。
vectorz = (vec <= 26);
//６ステップインバータhexの状態に従い各相にベクトル（vectorx、vectory、
//ivectorx、ivectory、vectorz）をわり当てる。
//（ゼロベクトルは電流の流れ込みvectorzと、電流のはき出し"0"の２種類がある）
when (hex == 0) then
{U = vectorx; V = 0; W = vectory;}
when (hex == 1) then
{U = vectorz; V = ivectory; W
= ivectorx;}
when (hex == 2) then
{U = vectory; V = vectorx; W
= 0;}
when (hex == 3) then
{U = ivectorx; V = vectorz; W
= ivectory;}
when (hex == 4) then
{U = 0; V = vectory; W = vectorx;}
when (hex ==5) then
{U = ivectory; V = ivectorx;
W = vectorz;}
//Ｕ，Ｖ，Ｗ信号から６相信号出力を作り、過電流時にはこの出力を
//スリーステート状態にする。
//UDL,VDL,WDLはU,V,W信号を外部ＣＲで遅らせた信号を入力する。。
UP = U & UDL; UP.OE = !PWM
& !OCOUT;
UN = !(U # UDL); UN.OE = !PWM
& !OCOUT;
VP = V &VDL; VP.OE = !PWM
& !OCOUT;
VN = !(V # VDL); VN.OE = !PWM
& !OCOUT;
WP = W & WDL; WP.OE = !PWM
& !OCOUT;
WN = !(W # WDL); WN.OE = !PWM
& !OCOUT;
//過電流信号ラッチ回路 過電流信号OCINが立ち上がるとレジスタOCLACHがラッチ
//され、ＰＷＭ出力を停止させる。 （解除は再電源投入）
OCLATCH.clk = OCIN;
OCLATCH := 1;
OCOUT = OCLATCH;
end INV3P
|
PWM波のチェック
XC9536のPWM出力 U相-V相の波形
2V/div
試運転
入力電圧AC１００Ｖで、回転速度の可変、トルク調整ＣＬＯＣＫの調整により出力電圧の可変も出来る事がわかり ました。
モーターの負荷装置が無いので詳細な特性は得る事が出来ませんでしたが無負荷時の相間電流波形を示します。
当初１周期３０ ステップのＳＩＮ波では、分解能が荒すぎ、制御出来ないかと思いましたが、ローターはなめらかに回転しまし た。
今回、回転速度と出力電圧調整はLOGIC ICによる簡単な発振回路によりマニュアルで実験しましたが、これをマイコンで行う事は
簡単でありもっと複雑な制御をする事も可能だと思います。
使用したＰＬＤ（ＸＣ９５３６）は８００ゲートとファミリの中では
一番小さな規模のものに収まり名古屋大須のパーツショップで４００円代で
入手出来ました。
作成したＰＬＤはセルの使用率が８８％で、ほぼ一杯となりましたが、ＸＣ９５７２（１６００ゲート）などを
使用すればＳＩＮ波の分解能も簡単に向上出来そうです。
改良版PLD XC9572
今回のPLDXC9536では容量の都合からハイサイドとローサイドドライブ出力切り替え時のの短絡を防止するためのデッドタイム回路を
入れることが出来ず、外部のCR回路としていましたが容量をもう１段階UPしたXC9572を使用することでこれらの外部回路が不要と
なりました。 改良版PLDについてはこちらをご欄下さい。
使用したＡＢＥＬ言語はマイコンのプログラムと比べ、複雑な割り込み処理などを意識せずに記述することが出来、
開発時間の短縮になりました。
さらに、ＦＬＡＳＨ ＲＯＭ構造で基板に実装したままでJTAGを使ったＩＳＰ（インシステムプログラミング）により
１万回以上の再書き込みが可能であるなどＤＥＢＵＧを楽に進める事が可能です。
シミュレーション
Xilinx Fandationに付属のALDEC社のシミュレータ
Xilinx社の書き込みTOOL
RS232ポートへ接続して書き込み及びDEBUGを行える
シリアルインターフェイス（写真上）
パラレルポートへ接続して書き込みが行える
パラレルインターフェイス（写真下）
[回路及びソフトウェア利用規程]
使用者がこれらの回路及びソフトウェア利用する場合、下記の条件を必ずお守り下さい。
著作権
著作権は全てMiniprobeが保持します。
改造
改造はご自由に行って下さい。Miniprobeに対し届けも必要ございませが、私本人の技術向上のため内容をご連絡頂けると助かります。
再配布
再配布はご自由に行って下さい。
免責
Miniprobeは使用者に対し、回路及びソフトウェアの動作責任を負いません。
またこれらの回路及びソフトウェアに起因して生じた、いかなる損害に対しても賠償、責任は負いません。
本規定は予告なく変更、施行されます。
参考文献
１） 見城尚志，「モーターのＡＢＣ」，講談社
２） 「プログラマブル．ロジック データブック」
ＸＩＬＩＮＸ社
３） 「ＩＳＰアプリケーションガイド」
ＸＩＬＩＮＸ社
４） 「ＡＢＥＬによるＡＳＩＣの設計技法」
ＣＱ出版社
RETURN  ご意見，アドバイスなどありましたらdesign@miniprobe.com にお願い致します
|
